Aminet 52/Aminet 52 (2002)(GTI - Schatztruhe)[!][Dec 2002].iso/Aminet/game/patch/WHDIGamesC-D.lzh/ClikClak.lha/ClikClakHD/Install

Text File | 2002-01-03 | 5KB | 240 lines

;****************************

(set #sub-dir "data")            ;sub directory containing data files
(set #osemu-file "OSEmu.400")        ;OSEmu file
(set #readme-file "ReadMe")        ;name of readme file
(set #docs-file "Instructions")        ;name of the docs file
(set #highs-file "highs")        ;name of high scores file
(set #cleanup "")            ;files to delete after install

;****************************
;----------------------------
; checks if given program is installed, if not abort install
; #program - to check

(procedure P_ChkRun
  (if
    (= 0 (run ("cd SYS:\nWhich %s" #program)))
    ("")
    (abort
      (cat
    "You must install \"" #program "\" first!\n"
    "It must be accessible via the path.\n"
    "You can find it in the WHDLoad package."
      )
    )
  )
)

(procedure P_ChkRunAminet
  (if
    (= 0 (run ("cd SYS:\nWhich %s" #program)))
    ("")
    (abort
      (cat
    "You must install \"" #program "\" first!\n"
    "It must be accessible via the path.\n"
    "You can find it on Aminet."
      )
    )
  )
)

;----------------------------
; Wait for inserting disk
; IN:  #AD_disk - name of disk
; OUT: -

(procedure P_disk
  (askdisk
    (dest #AD_disk)
    (prompt ("\nInsert Disk \"%s\" in any drive!" #AD_disk))
    (help @askdisk-help)
  )
)

;****************************

(if
  (exists #readme-file)
  (if
    (= 0 (run ("SYS:Utilities/Multiview %s" #readme-file)))
    ("")
    (run ("SYS:Utilities/More %s" #readme-file))
  )
)

(set #program "WHDLoad")
(P_ChkRun)

(set #program "xfddecrunch")
(P_ChkRunAminet)

(if
  (getenv "WHDLInstPath")
  (set @default-dest (getenv "WHDLInstPath"))
)
(set #dest
  (askdir
    (prompt ("Where should \"%s\" be installed?\nA drawer \"%s\" will be automatically created." @app-name @app-name))
    (help @askdir-help)
    (default @default-dest)
    (disk)
  )
)
(run ("setenv WHDLInstPath \"%s\"\ncopy ENV:WHDLInstPath ENVARC:" @default-dest))
(set #dest (tackon #dest @app-name))
(if
  (exists #dest)
  (
    (set #choice
      (askbool
        (prompt ("\nDirectory \"%s\" already exists.\n Should it be deleted?" #dest))
        (default 1)
        (choices "Delete" "Skip")
        (help @askbool-help)
      )
    )
    (if
      (= #choice 1)
      (run ("Delete \"%s\" \"%s.info\" All" #dest #dest))
    )
  )
)
(makedir #dest
  (help @makedir-help)
  (infos)
)

;----------------------------

(copyfiles
  (help @copyfiles-help)
  (source ("%s.Slave" @app-name))
  (dest #dest)
)
(if
  (exists ("%s.newicon" @app-name))
  (set #icon
    (askchoice
      (prompt "\nWhich icon would you like to install?\n")
      (default 0)
      (choices "Normal" "NewIcon" "GlowIcon")
      (help @askchoice-help)
    )
  )
  (set #icon 0)
)
(select #icon
  (set #icon ("%s.inf" @app-name))
  (set #icon ("%s.newicon" @app-name))
  (set #icon ("%s.glowicon" @app-name))
)
(copyfiles
  (help @copyfiles-help)
  (source #icon)
  (newname ("%s.info" @app-name))
  (dest #dest)
)
(tooltype
  (dest (tackon #dest @app-name))
  (settooltype "Slave" ("%s.Slave" @app-name))
  (setdefaulttool "WHDLoad")
  (setstack 10240)
  (noposition)
)
(if
  (exists #readme-file)
  (copyfiles
    (help @copyfiles-help)
    (source #readme-file)
    (dest #dest)
  )
)
(if
  (exists ("%s.info" #readme-file))
  (
    (copyfiles
      (help @copyfiles-help)
      (source ("%s.info" #readme-file))
      (dest #dest)
    )
    (tooltype
      (dest (tackon #dest #readme-file))
      (noposition)
    )
  )
)
(if
  (exists #docs-file)
  (copyfiles
    (help @copyfiles-help)
    (source #docs-file)
    (dest #dest)
  )
)
(if
  (exists ("%s.info" #docs-file))
  (
    (copyfiles
      (help @copyfiles-help)
      (source ("%s.info" #docs-file))
      (dest #dest)
    )
    (tooltype
      (dest (tackon #dest #docs-file))
      (noposition)
    )
  )
)

(if
  (= #sub-dir "")
  ("")
  (
    (set #dest (tackon #dest #sub-dir))
    (makedir #dest
      (help @makedir-help)
    )
  )
)
(if
  (exists #osemu-file)
  (copyfiles
    (help @copyfiles-help)
    (source #osemu-file)
    (dest #dest)
  )
)
(if
  (exists #highs-file)
  (copyfiles
    (help @copyfiles-help)
    (source #highs-file)
    (dest #dest)
  )
)

;----------------------------

(set #AD_disk "Clik_Clak")
(P_disk)
(copyfiles
  (help @copyfiles-help)
  (source ("%s:" #AD_disk))
  (dest #dest)
  (pattern "~(s|Trashcan|addmem|addmem2|system-configuration|Trashcan.info)")
)

(if
  (= 0 (run "xfddecrunch " (tackon #dest "Clik") " >con://///WAIT/CLOSE/AUTO"))
  ("")
  (abort "\"XFDDecrunch\" has failed")
)

;----------------------------

(run ("Delete %s ALL QUIET FORCE" #cleanup))

(exit)